# Workflows aus einen laufenden Workflow heraus starten

**URL:** <https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179>\
**Category:** enaio®\
**Tags:** workflow\
**Created:** [5. Oktober 2021 um 14:03 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179 "2021-10-05T14:03:40Z")\
**Posts on this page:** 20\
**Page:** 1

<div class="post-metadata">

**Author:** ![uw](https://ecm.community/user_avatar/ecm.community/uw/32/695_2.png) [@uw](https://ecm.community/u/uw)\
**Post date:** [5. Oktober 2021 um 14:03 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/1 "2021-10-05T14:03:40Z")

</div>

Aus einer Kundenanfrage und einem sehr nützlichen Hinweisen von Paavo (Vielen Dank nach Berlin) habe ich dieses Codebeispiel zusammengebaut.

Mit der Methode `StartProcess` kann man innerhalb eines Server-Events weitere Workflows starten.

Wichtig, die weiteren Workflows haben als Creator einen technischen Benutzer. Daher sollte dieser bei Bedarf als Variable mitgegeben werden und dann der ActivityPerformer z.B. so gesetzt werden.

```auto
thisProcess.SetActivityPerformer thisProcess.CurrentActivity.Activityid, wfvariables.StartBenutzer.Value

```

# Beispiel

```vb
' Parameter:
' -> WFName (String): Name des Workflows
'
' -> InputVariables (Scripting.Dictionary): Dict der zu übergebenen Parameter. 
'
' Beispiel:
' Dim InputVariables: Set InputVariables = CreateObject("Scripting.Dictionary")
' InputVariables.Add "VariablenName", "VariablenWert"
'
' -> InputFiles (Array(Scripting.Dictionary)): Array aus Dict. Dict muss die Schlüssel id, typeId, inWorkspace, location (1 = Objekt bereits zugeordnet 2 = Objekt liegt in der WF-Ablage )
' 
' Beispiel:
' Dim Doc: Set Doc = CreateObject("Scripting.Dictionary")
' Doc.Add "id", 12345
' Doc.Add "typeId", 262148
' Doc.Add "inWorkspace", True
' Doc.Add "location", 1
' InputFiles = Array(Doc)

Function StartProcess(WfName, InputVariables, InputFiles)
	Dim Models: Set Models = wfsystem.getactiveworkflowmodels 
	For i = 0 To Models.Count - 1 
		Dim Model: Set Model = Models.Item(i) 
		
		' Suche nach WF Model
		If model.name = WfName then 
			' Setze Variablen 
			Dim Variables: Set Variables = Model.InputVariables 
			
			For Each VarName In InputVariables.Keys()
				Variables.item(VarName).value = InputVariables(VarName)
			Next
			
			' Setze Objekte in der Workflow Akte
	    	Dim Files: Set Files = Model.File 

			For Each CurFile In InputFiles
				Files.AddFileObject CurFile("id"),CurFile("typeId"), CurFile("inWorkspace"), CurFile("location")
			Next
			
	  		'Starte Prozess   
			StartProcess = Model.StartProcess(Files, Variables) 
			Exit Function
		 end if 
 	  Next
 	  
 	  ' Workflow nicht gefunden
 	  Err.Raise 1, "Workflowmodel " & WfName & " nicht gefunden"	  
End Function

Function Main
	If wfvariables.ElternProzess.Value = "" Then
	
		Dim InputVariables: Set InputVariables = CreateObject("Scripting.Dictionary")
		InputVariables.Add "ElternProzess", thisprocess.ProcessId
		InputVariables.Add "StartBenutzer", thisprocess.Creator
		
		Dim Doc: Set Doc = CreateObject("Scripting.Dictionary")
		Doc.Add "id", thisprocess.WFFile.FileObjects.Item(0).Id
		Doc.Add "typeId", thisprocess.WFFile.FileObjects.Item(0).ObjectType
		Doc.Add "inWorkspace", True
		Doc.Add "location", 1
		
		InputFiles = Array(Doc)
	
		StartProcess "Subprozess", InputVariables, InputFiles
		
		wfvariables.StartBenutzer.Value = thisprocess.Creator
		
	End If
End Function

Main

```

Ich hoffe das Beispiel hilft weiter.

---

<div class="post-metadata">

**Author:** ![Dave](https://ecm.community/letter_avatar_proxy/v4/letter/d/ee7513/32.png) [@Dave](https://ecm.community/u/Dave)\
**Post date:** [4. Juli 2023 um 08:25 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/2 "2023-07-04T08:25:17Z")

</div>

Hallo,

ich möchte diese Funktion gerade bei einem unserer Workflows in der EndActivity einer bestimmten Aktivität einbauen, damit im Hintergrund ein anderer Workflow gestartet wird.

Jedoch gibt es ein Problem mit der Übergabe der InputVariables. Ich habe die gleichen Variablen benutzt wie in dem Beispiel und diese als Variablen im Quell- und Ziel Workflow eingerichtet.

Es kommt folgende Fehlermeldung:

Beim Parsen des Skriptes ist ein Fehler (0x80070057) aufgetreten (Zeile 52, Zeichen 3):  
Quelle: oxjobwfm.ComDataFields.1  
Beschreibung: Falscher Parameter.

Zeile: not available

Ich habe schon einiges ausprobiert aber hat nichts geholfen. Hat jemand vielleicht noch Ideen, an was es liegen könnte?

Grüße

---

<div class="post-metadata">

**Author:** ![rk](https://ecm.community/user_avatar/ecm.community/rk/32/679_2.png) [@rk](https://ecm.community/u/rk)\
**Post date:** [4. Juli 2023 um 08:36 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/3 "2023-07-04T08:36:50Z")

</div>

Hallo @Dave, wäre es möglich, die Zeile 52 und ggf. etwas Umland hier zu posten oder ist das aus Datenschutz/-Eigentumsrechten schlecht?

Taucht der Fehler auch im Enterprise Manager bei der Job-Überwachung auf oder bleibt dieser dort unsichtbar (was ich annehme)?

---

<div class="post-metadata">

**Author:** ![Dave](https://ecm.community/letter_avatar_proxy/v4/letter/d/ee7513/32.png) [@Dave](https://ecm.community/u/Dave)\
**Post date:** [4. Juli 2023 um 08:56 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/4 "2023-07-04T08:56:41Z")

</div>

Hallo @rk und danke für die schnelle Antwort.

Hier ist das Skript der ganzen EndActivity. Wenn eine bestimmte Option ausgewählt wird, soll der Workflow im Hintergrund gestartet werden:

```auto
If wfvariables.iantragsauswahl.Value = antrag_benutzer then 
	wfvariables.inaechsteAktivitaet.Value = Aktivitaet_end_sdurchfuehrung
	AddProtocolItem wfvariables.santragsteller.Value, "Antrag für Benutzer wurde vom Antragsteller gewählt - IT-Benutzeranträge wird im Hintergrund gestartet"

Function StartProcess(WfName, InputVariables, InputFiles)
	Dim Models: Set Models = wfsystem.getactiveworkflowmodels 
	For i = 0 To Models.Count - 1 
		Dim Model: Set Model = Models.Item(i) 
		
		' Suche nach WF Model
		If model.name = WfName then 
			' Setze Variablen 
			Dim Variables: Set Variables = Model.InputVariables 
			
			For Each key In InputVariables.Keys()
				Variables.item(key).value = InputVariables(key)
			Next
			
			' Setze Objekte in der Workflow Akte
	    	Dim Files: Set Files = Model.File 
			
	  		'Starte Prozess   
			StartProcess = Model.StartProcess(Files, Variables) 
			Exit Function
		 end if 
 	  Next
 	  
 	  ' Workflow nicht gefunden
 	  Err.Raise 1, "Workflowmodel " & WfName & " nicht gefunden"	  
End Function

Function Main
	'If wfvariables.ElternProzess.Value = "" Then
	
		Dim InputVariables: Set InputVariables = CreateObject("Scripting.Dictionary")
		InputVariables.Add "ElternProzess", thisprocess.ProcessId
		InputVariables.Add "StartBenutzer", thisprocess.Creator
		
		InputFiles = 0
	
		StartProcess "IT-Benutzeranträge 2.0", InputVariables, InputFiles
		
		wfvariables.StartBenutzer.Value = thisprocess.Creator
		
	'End If
End Function

Main

elseif wfvariables.iantragsauswahl.Value = antrag_verzeichnisberechtigung then 
	wfvariables.inaechsteAktivitaet.Value = Aktivitaet_antragstellen
	AddProtocolItem wfvariables.santragsteller.Value, "Antrag für Verzeichnisberechtigung wurde vom Antragsteller gewählt"
elseif wfvariables.iantragsauswahl.Value = antrag_inetantrag then
	wfvariables.inaechsteAktivitaet.Value = Aktivitaet_inetantrag
	AddProtocolItem wfvariables.santragsteller.Value, "Antrag für Internetfreigabe wurde vom Antragsteller gewählt"
end if

```

Die betroffene Zeile laut Fehler ist diese:

```auto
For Each key In InputVariables.Keys()

```

In der Job Überwachung habe ich keinen Fehler gefunden.

---

<div class="post-metadata">

**Author:** ![rk](https://ecm.community/user_avatar/ecm.community/rk/32/679_2.png) [@rk](https://ecm.community/u/rk)\
**Post date:** [4. Juli 2023 um 12:28 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/5 "2023-07-04T12:28:15Z")

</div>

Kann es sein, dass da etwas durcheinander gekommen ist und der Block „zerrissen“ ist:

```plaintext
If wfvariables.iantragsauswahl.Value = antrag_benutzer then 
	wfvariables.inaechsteAktivitaet.Value = Aktivitaet_end_sdurchfuehrung
	AddProtocolItem wfvariables.santragsteller.Value, "Antrag für Benutzer wurde vom Antragsteller gewählt - IT-Benutzeranträge wird im Hintergrund gestartet"
elseif wfvariables.iantragsauswahl.Value = antrag_verzeichnisberechtigung then 
	wfvariables.inaechsteAktivitaet.Value = Aktivitaet_antragstellen
	AddProtocolItem wfvariables.santragsteller.Value, "Antrag für Verzeichnisberechtigung wurde vom Antragsteller gewählt"
elseif wfvariables.iantragsauswahl.Value = antrag_inetantrag then
	wfvariables.inaechsteAktivitaet.Value = Aktivitaet_inetantrag
	AddProtocolItem wfvariables.santragsteller.Value, "Antrag für Internetfreigabe wurde vom Antragsteller gewählt"
end if

```

Auf jeden Fall wirken die Zeilen 4 und 49 auf mich so, als würden da `If`-Blöcke falsch geschlossen/geöffnet:

 ![grafik](https://ecm.community/uploads/default/original/1X/1ef2dca1684bb48afa870ed472a302796099aa75.png)

 ![grafik](https://ecm.community/uploads/default/original/1X/6dfa17be33b252181205abd24905c029be318730.png)

---

<div class="post-metadata">

**Author:** ![Dave](https://ecm.community/letter_avatar_proxy/v4/letter/d/ee7513/32.png) [@Dave](https://ecm.community/u/Dave)\
**Post date:** [4. Juli 2023 um 12:51 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/6 "2023-07-04T12:51:09Z")

</div>

Ich habe die Functions jetzt mal ausgelagert und nochmals kontrolliert:

```auto
If wfvariables.iantragsauswahl.Value = antrag_benutzer then
	wfvariables.inaechsteAktivitaet.Value = Aktivitaet_end_sdurchfuehrung
	AddProtocolItem wfvariables.santragsteller.Value, "Antrag für Benutzer wurde vom Antragsteller gewählt - IT-Benutzeranträge wird im Hintergrund gestartet"
	Main
elseif wfvariables.iantragsauswahl.Value = antrag_verzeichnisberechtigung then 
	wfvariables.inaechsteAktivitaet.Value = Aktivitaet_antragstellen
	AddProtocolItem wfvariables.santragsteller.Value, "Antrag für Verzeichnisberechtigung wurde vom Antragsteller gewählt"
elseif wfvariables.iantragsauswahl.Value = antrag_inetantrag then
	wfvariables.inaechsteAktivitaet.Value = Aktivitaet_inetantrag
	AddProtocolItem wfvariables.santragsteller.Value, "Antrag für Internetfreigabe wurde vom Antragsteller gewählt"
end if

```

Allerdings ist der Fehler der gleiche geblieben. Selbst wenn ich die Inputvariables nicht in ein Dictionary schreibe, sondern direkt angebe, bringt er denselben Fehler.

Grüße

---

<div class="post-metadata">

**Author:** ![Dave](https://ecm.community/letter_avatar_proxy/v4/letter/d/ee7513/32.png) [@Dave](https://ecm.community/u/Dave)\
**Post date:** [4. Juli 2023 um 13:49 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/7 "2023-07-04T13:49:35Z")

</div>

Ich habe gerade nochmal die Job Überwachung nebenher laufen lassen. So wie es aussieht, existieren die Parameter und haben auch Werte:

![image](https://ecm.community/uploads/default/original/1X/0f5709ff0e059133a1ee4f33b426505ae10f8517.png)

---

<div class="post-metadata">

**Author:** ![rk](https://ecm.community/user_avatar/ecm.community/rk/32/679_2.png) [@rk](https://ecm.community/u/rk)\
**Post date:** [5. Juli 2023 um 05:16 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/8 "2023-07-05T05:16:04Z")

</div>

> [@Dave](#):
>
> Allerdings ist der Fehler der gleiche geblieben.

Da das ursprüngliche Event (ohne es im Editor selbst getestet zu haben) syntaktisch eine Fehlermeldung hätte melden sollte, überrascht mich das. Die Syntaxprüfung ist mit der Stelle bzw. dem ganzen Event glücklich, oder?

Eventuell löst der Aufruf einen weiteren Event aus, aber das ist ohne mehr Kontext vermutlich nicht zu sagen.

---

<div class="post-metadata">

**Author:** ![Dave](https://ecm.community/letter_avatar_proxy/v4/letter/d/ee7513/32.png) [@Dave](https://ecm.community/u/Dave)\
**Post date:** [5. Juli 2023 um 06:31 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/9 "2023-07-05T06:31:07Z")

</div>

Guten Morgen,

zum Test habe ich einen neuen Workflow erstellt, der nur eine Aktivität besitzt. In der EndActivity dieser Aktivität wird nur das oben genannte Script zum Starten eines neuen Prozesses ausgeführt. Syntaxprüfung passt auch. Leider immer noch der besagte Fehler.

Ich habe parallel ein Ticket bei OS aufgemacht, dort kam leider noch keine Rückmeldung.

---

<div class="post-metadata">

**Author:** ![uw](https://ecm.community/user_avatar/ecm.community/uw/32/695_2.png) [@uw](https://ecm.community/u/uw)\
**Post date:** [5. Juli 2023 um 07:02 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/10 "2023-07-05T07:02:53Z")

</div>

@rk Ich bin etwas überrascht, aber man darf in VBS innerhalb von If Blöcken Funktionen definieren.

Ich habe dies kurz getestet.

```plaintext
If true Then
    Function Test()
        msgbox "Funktioniert"
    End Function
    Test
End If

```

In sofern ist es kein Syntax Problem.

---

<div class="post-metadata">

**Author:** ![uw](https://ecm.community/user_avatar/ecm.community/uw/32/695_2.png) [@uw](https://ecm.community/u/uw)\
**Post date:** [5. Juli 2023 um 07:28 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/11 "2023-07-05T07:28:20Z")

</div>

> [@Dave](#):
>
> Parameter

Guten Morgen @Dave,

Kann es sein, dass der Fehler eigentlich im zu startenden `Workflow IT-Benutzeranträge 2.0` passiert?

Können Sie prüfen ob alle Variablen die sie im Aufruf des StartProcess Aufrufs mitsenden im Prozess `Workflow IT-Benutzeranträge 2.0` existieren und die Datentypen übereinstimmen?

Mfg Uli

---

<div class="post-metadata">

**Author:** ![rk](https://ecm.community/user_avatar/ecm.community/rk/32/679_2.png) [@rk](https://ecm.community/u/rk)\
**Post date:** [5. Juli 2023 um 07:41 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/12 "2023-07-05T07:41:39Z")

</div>

Verrückt, habe ich noch nie gesehen, aber cool zu wissen. Danke auch an @Dave für die Info.

---

<div class="post-metadata">

**Author:** ![Dave](https://ecm.community/letter_avatar_proxy/v4/letter/d/ee7513/32.png) [@Dave](https://ecm.community/u/Dave)\
**Post date:** [5. Juli 2023 um 07:57 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/13 "2023-07-05T07:57:19Z")

</div>

Hallo @uw ,

folgende Variablen sind in dem Quell- und Ziel Workflow mit dem gleichen Datentyp angelegt:  
 ![image](https://ecm.community/uploads/default/original/1X/f807cc7662aa5745ac5511bdfb3b88af1ef00f39.png)

![image](https://ecm.community/uploads/default/original/1X/85f6c0e0c1c01cb48e7c54dde439ea32ec2053b5.png)

Und dann auch jeweils in den Anwendungen als Parameter hinterlegt und der entsprechenden Aktivität zugeordnet.

Quellworkflow:  
 ![image](https://ecm.community/uploads/default/original/1X/33a5a098914a24f2ed8801a81ee3190f1c68d612.png)

Ziel Workflow:  
 ![image](https://ecm.community/uploads/default/original/1X/ea3b136d5315ab2d587637435aab87706f3236d7.png)

---

<div class="post-metadata">

**Author:** ![uw](https://ecm.community/user_avatar/ecm.community/uw/32/695_2.png) [@uw](https://ecm.community/u/uw)\
**Post date:** [5. Juli 2023 um 08:57 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/14 "2023-07-05T08:57:23Z")

</div>

@Dave Wie sieht der Code der StartActivity in `Workflow IT-Benutzeranträge 2.0` aus?  
Könnte dort der eigentliche Fehler auftreten?

Sehen Sie im Workflow Administrator gescheiterte `Workflow IT-Benutzeranträge 2.0` Instanzen?

---

<div class="post-metadata">

**Author:** ![Dave](https://ecm.community/letter_avatar_proxy/v4/letter/d/ee7513/32.png) [@Dave](https://ecm.community/u/Dave)\
**Post date:** [5. Juli 2023 um 09:12 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/15 "2023-07-05T09:12:00Z")

</div>

Das ist der Code in der StartActivity:

```auto
'Antragsart auswählen|StartActivity
Dim RCHelper: Set RCHelper = New RCHelperClass
Dim RC: Set RC = RunningContext
RCHelper.SetUsername TECHNICALUSER

'Prozessersteller bekommt die Aktivität
thisProcess.SetActivityPerformer thisProcess.CurrentActivity.Activityid, wfvariables.StartBenutzer.Value

'Vorbelegung
wfvariables.iAntragsart.Value = DEFAULT

```

Da passiert eigentlich nicht so viel, außer dass ich den Performer mit dem übergebenen Parameter setzen möchte.

Ich habe zum Test auch mal die Function zum Prozess starten ohne zu übergebene Parameter ausgeführt und da hat es funktioniert. Es hat eine Instanz des Workflows erstellt und gestartet (war sichtbar im Workflow Administrator), aber halt keinem Benutzer zugeordnet, da ich es nicht mitgeliefert habe.

---

<div class="post-metadata">

**Author:** ![Dave](https://ecm.community/letter_avatar_proxy/v4/letter/d/ee7513/32.png) [@Dave](https://ecm.community/u/Dave)\
**Post date:** [5. Juli 2023 um 09:13 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/16 "2023-07-05T09:13:12Z")

</div>

Gescheiterte Instanzen des Workflows IT-Benutzeranträge 2.0 sehe ich nicht, es scheint so, dass er gar nicht so weit kommt.

---

<div class="post-metadata">

**Author:** ![tordeu](https://ecm.community/user_avatar/ecm.community/tordeu/32/400_2.png) [@tordeu](https://ecm.community/u/tordeu)\
**Post date:** [11. Juli 2023 um 11:56 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/17 "2023-07-11T11:56:21Z")

</div>

Sind StartBenutzer und ElternProzess im Zielprozess nur als Eingabeparamter einer Anwendung hinterlegt oder auch als Eingabeparameter **des Modells**?

Hier ein Beispiel eines Workflows, den ich erfolgreich aus dem DMS mit Eingabeparametern starten kann (ein Start aus einem anderen Workflow habe ich noch nicht getestet):

![image](https://ecm.community/uploads/default/original/1X/6e7879e437cec12ae1363cb1529934c9cb4d46e6.png)

---

<div class="post-metadata">

**Author:** ![Dave](https://ecm.community/letter_avatar_proxy/v4/letter/d/ee7513/32.png) [@Dave](https://ecm.community/u/Dave)\
**Post date:** [11. Juli 2023 um 12:22 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/18 "2023-07-11T12:22:54Z")

</div>

Hallo @tordeu ,

danke für die Nachricht. Das war tatsächlich noch das Problem, ich hatte die Parameter für das Modell noch nicht hinterlegt.

Nachdem ich diese dort entsprechend eingefügt habe, hat es funktioniert.

Danke für die Unterstützung!

Grüße

---

<div class="post-metadata">

**Author:** ![Dave](https://ecm.community/letter_avatar_proxy/v4/letter/d/ee7513/32.png) [@Dave](https://ecm.community/u/Dave)\
**Post date:** [21. November 2023 um 10:22 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/19 "2023-11-21T10:22:59Z")

</div>

Guten Morgen zusammen,

ich hätte nochmal eine Frage, welche dieses Thema streift, vielleicht kann mir ja jemand weiterhelfen.

Und zwar starte ich über ein Server-Event einen Workflow aus einem anderen Workflow heraus.

Als Ersteller wird dann automatisch ein Server User gesetzt (WF-System3). Der Nachteil ist natürlich jetzt, dass die Person, die den ursprünglichen Workflow gestartet hat, den Workflow nicht unter „Laufende Workflows“ sieht, da er nicht der Creator ist.

Jetzt wollte ich in dem Workflow den tatsächlichen Starter als Prozessverantwortlichen hinzufügen.

Allerdings kommt bei dem Versuch immer dieser Fehler:

 ![image](https://ecm.community/uploads/default/original/1X/8952b880aa4432d2c2b705f91fe30b2b7247f865.png)

Vor dem Hinzufügen des Prozessverantwortlichen möchte er die aktuellen immer auslesen und das Server-Objekt, das den Workflow erstellt hat, gibt es nicht. Dabei läuft er auf Fehler.

Hat zufällig jemand damit Erfahrung oder eventuell einen anderen Lösungsansatz für das Problem?

Viele Grüße  
Dave

---

<div class="post-metadata">

**Author:** ![rk](https://ecm.community/user_avatar/ecm.community/rk/32/679_2.png) [@rk](https://ecm.community/u/rk)\
**Post date:** [21. November 2023 um 10:46 UTC](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179/20 "2023-11-21T10:46:20Z")

</div>

Hallo @Dave, ich finde vor allem die Meldung `Das Objekt '000...000003' ist ... nicht vorhanden` total überraschend, woher kommt den diese GUID (?) mit diesem sehr konkreten Wert 3?

Wie muss ich mir den Code vorstellen, wird da `thisProcess.Creator` direkt gesetzt?

[Nächste Seite](https://ecm.community/t/workflows-aus-einen-laufenden-workflow-heraus-starten/179.md?page=2)