Beispiel: enaio RichtClient Andwendung für das Kontext Menü

Embedded Office for enaio® und yuuvis®
1

Hier ein kleines Beispiel wie man eine enaio Andwendung erstellen kann, welche alle makierten Dokumente als Browser Tabs öffnet.

Konfiguration

grafik
grafik682×553 53.8 KB

Code:

Dim WshShell: Set WshShell = CreateObject("WScript.shell")
Dim FSO: Set FSO = CreateObject("Scripting.FileSystemObject")

Dim Application : Set Application = createobject("optimal_AS.application")
Dim DrtSession: Set DrtSession = Application.getDrtSession()

Dim SessionGuid: SessionGuid = DrtSession.SessionGuid

Function Main
	Dim Args: Set Args = WScript.Arguments
	
	If Args.Count = 0 Then
		MsgBox "Externe Application mit Parameter %i starten"
		Exit Function
	End If 
	
	GatewayUrl = GetSvrRegEntry("Services\Gateway\API")
	
	Dim InfoFilePath: InfoFilePath = Args(0)
	Dim InfoFile: Set InfoFile = FSO.OpenTextFile(InfoFilePath, 1)

	Do Until InfoFile.AtEndOfStream
		Dim Parameter: Parameter = InfoFile.ReadLine
		ParameterParts = Split(Parameter, ",")
		WshShell.run GatewayUrl & "/office/desktop/edit/edit/" & ParameterParts(1) & "/" &  ParameterParts(0) & "?sessionguid=" & SessionGuid
	Loop
End Function

Function GetSvrRegEntry(key)
	set regjob = DrtSession.CreateJob("krn", "REGetRegValue")
	regjob.AddInParamString "Name", key
	result = regjob.execute()
	value = regjob.GetOutParamString("Value")
	if (result <> 0) then
		'maybe some day error logging
	end if
	GetSvrRegEntry = value
End Function

Main()

Das VBScript muss für die Clients über den Pfad lesend erreichbar sein. Daher ist es am besten, diesen auf eine entsprechende Windows Netzwerkfreigabe bereitzustellen.

1 „Gefällt mir“